So hängen Sie Laufwerke an den Navigationsbereich im Datei-Explorer unter Windows 10 an

 

Im Navigationsbereich des Datei-Explorers sind standardmäßig einige Elemente befestigt. Eines dieser Elemente ist This PC. Wenn Sie es erweitern, können Sie auf Ihr Windows ’ zugreifen. Bibliotheken sowie die Laufwerke auf Ihrer Festplatte. Wenn Sie zusätzliche Elemente an den Navigationsbereich anheften müssen, können Sie sie unter ‘ Schnellzugriff ’ Sie können hier sowohl Laufwerke als auch Ordner anheften. Wenn Sie Laufwerke lieber an den Navigationsbereich anheften, so dass sie als eigenes Element anstelle eines Unterelements unter „Dieser PC“ oder „Schnellzugriff“ angezeigt werden, können Sie dies tun. Dazu benötigen Sie ein Batch-Skript.

 

Dieses Skript wurde vom Superuser-Benutzer JosefZ geschrieben und kann die C- und D-Laufwerke an den Navigationsbereich im Datei-Explorer anschließen. Das Skript kann geändert werden, um auch andere Laufwerke zu fixieren.

Registrierungsschlüssel sichern

Bevor Sie dieses Skript verwenden, müssen Sie einen Registrierungsschlüssel sichern. Öffnen Sie die Windows-Registrierung und navigieren Sie zum folgenden Speicherort.

HKEY_CURRENT_USER\Software\Microsoft\Windows\CurrentVersion\Explorer\HideDesktopIcons\NewStartPanel

Klicken Sie mit der rechten Maustaste auf den Schlüssel NewStartPanel, und exportieren Sie ihn an einem sicheren Ort. Dies ist eine Vorsichtsmaßnahme, die Sie auf jeden Fall treffen sollten.

Laufwerk an Navigationsbereich anhängen

Öffnen Sie den Editor und fügen Sie den folgenden Code ein. Speichern Sie die Datei unter einem beliebigen Namen und mit der Dateierweiterung BAT.

@ECHO OFF
SETLOCAL EnableExtensions
set "_icon=%%SystemRoot%%\system32\imageres.dll,27"
set "_name=D DataDisk"
set "_guid=ffffffff-ffff-ffff-0000-00000000000d"
set "_target=d:\\"

set "_regK=HKCU\Software\Classes\CLSID"
set "_regE=HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer"
if NOT "%~1"=="" goto :deleAll
reg add %_regK%\{%_guid%} /ve /t REG_SZ /d "%_name%" /f
reg add %_regK%\{%_guid%}\DefaultIcon /ve /t REG_EXPAND_SZ /d %_icon% /f
reg add %_regK%\{%_guid%} /v System.IsPinnedToNameSpaceTree /t REG_DWORD /d 0x1 /f
reg add %_regK%\{%_guid%} /v SortOrderIndex /t REG_DWORD /d 0x42 /f
reg add %_regK%\{%_guid%}\InProcServer32 /ve /t REG_EXPAND_SZ /d %%systemroot%%\system32\shell32.dll /f
reg add %_regK%\{%_guid%}\Instance /v CLSID /t REG_SZ /d {0E5AAE11-A475-4c5b-AB00-C66DE400274E} /f
reg add %_regK%\{%_guid%}\Instance\InitPropertyBag /v Attributes /t REG_DWORD /d 0x11 /f
reg add %_regK%\{%_guid%}\Instance\InitPropertyBag /v TargetFolderPath /t REG_EXPAND_SZ /d "%_target%" /f
reg add %_regK%\{%_guid%}\ShellFolder /v FolderValueFlags /t REG_DWORD /d 0x28 /f
reg add %_regK%\{%_guid%}\ShellFolder /v Attributes /t REG_DWORD /d 0xF080004D /f
reg add %_regE%\Desktop\NameSpace\{%_guid%} /ve /t REG_SZ /d "%_name%" /f
reg add %_regE%\HideDesktopIcons\NewStartPanel /v {%_guid%} /t REG_DWORD /d 0x1 /f

:endlocal
ENDLOCAL
goto :eof

:deleAll
reg delete %_regK%\{%_guid%} /f
reg delete %_regE%\Desktop\NameSpace\{%_guid%} /f
reg delete %_regE%\HideDesktopIcons\NewStartPanel /v {%_guid%} /f
goto :endlocal

So hängen Sie Laufwerke an den Navigationsbereich im Datei-Explorer unter Windows 10 an

EMPFOHLEN FÜR SIE

So hängen Sie Laufwerke an den Navigationsbereich im Datei-Explorer unter Windows 10 an

Windows

So aktivieren / Deaktivieren In Windows 10

So hängen Sie Laufwerke an den Navigationsbereich im Datei-Explorer unter Windows 10 an

Windows

So verbergen Sie ein Laufwerk im Datei-Explorer, ohne es unter Windows 10 aufzuheben

Nach dem Speichern Klicken Sie mit der rechten Maustaste auf die Datei und führen Sie sie mit Administratorrechten aus. Das obige Skript fügt das D-Laufwerk zum Navigationsbereich im Datei-Explorer hinzu.

So hängen Sie Laufwerke an den Navigationsbereich im Datei-Explorer unter Windows 10 an

Um das Laufwerk C hinzuzufügen, müssen Sie das obige Skript ändern. Insbesondere müssen Sie die Zeilen 3-6 und die folgenden Zeilen ändern.

set "_icon=%%SystemRoot%%\system32\imageres.dll,31"
set "_name=c SystemDisk"
set "_guid=ffffffff-ffff-ffff-0000-00000000000c"
set "_target=c:\\"

Vergleichen Sie die beiden Zeilengruppen und Sie können sie änderndas Skript, damit es jedes Laufwerk Ihrer Wahl hinzufügen kann.

Um ein Laufwerk zu entfernen, öffnen Sie die Eingabeaufforderung mit Administratorrechten und CD in dem Ordner, in dem Sie die Skripts gespeichert haben. Führen Sie den folgenden Befehl aus, ersetzen Sie jedoch ‘ name-of-script.bat ’ mit dem Namen, mit dem Sie das Skript gespeichert haben.

name-of-script.bat x

Sie müssen dies für alle Laufwerke ausführen, die Sie im Navigationsbereich gepinnt haben. Wenn der Befehl zu Problemen führt, stellen Sie den gesicherten Registrierungsschlüssel wieder her.

ABONNIEREN SIE UNSEREN

NEWSLETTER

Erhalten Sie tägliche Tipps in Ihrem Posteingang. Nehmen Sie an 35.000 anderen Lesern teil

q , quelle

Zusammenhängende Posts:

Schreibe einen Kommentar

Deine E-Mail-Adresse wird nicht veröffentlicht. Erforderliche Felder sind mit * markiert.